Antonio Cordero Balcazar
db43d409f8
* error control when reading wildcard or mapping files, and second chance for files with incorrect encoding. * fix processing inside extranetwork tag.
167 lines
9.1 KiB
Plaintext
167 lines
9.1 KiB
Plaintext
%import common (LETTER, DIGIT, INT, CNAME, SIGNED_NUMBER, NUMBER)
|
|
|
|
_WHITESPACE: /\s+/
|
|
STRING: /("(?!"").*?(?<!\\)(\\\\)*?"|'(?!'').*?(?<!\\)(\\\\)*?')/i
|
|
BOOLEAN: /true|false/i
|
|
WILDCARD_NAME: /(?:(?!__|\$\$|[('"])\S)+/
|
|
INDEX: INT | IDENTIFIER
|
|
IDENTIFIER: CNAME
|
|
SIMPLEVALUE: STRING | SIGNED_NUMBER | BOOLEAN
|
|
|
|
// plain text and weights
|
|
?plain: /((?!__|\bAND\b|\${)[^\\()\[\]:<>${]|\\.)+/s // exclude only the starting ones
|
|
?plain_choice: /((?!__|\bAND\b|\${|\$\$)[^\\()\[\]:<>${|}~@]|\\.)+/s // add the specific internal choice ones
|
|
?plain_alternate: /((?!__|\bAND\b|\${)[^\\()\[\]:<>${|]|\\.)+/s // add the specific internal alternate ones
|
|
?plain_var: /((?!__|\bAND\b|\${)[^\\()\[\]:<>${}]|\\.)+/s // add the specific internal var ones
|
|
?specialchars: /[_{()\[\]:<>]|\$(?![{$])/ // include only the starting ones
|
|
?specialchars_negtag: /[_{()\[\]:<>!|}]|\$(?![{$])/ // add the internal negtag ones
|
|
?specialchars_alternate: /[_{()\[\]:<>|]|\$(?![{$])/ // add the internal alternate ones
|
|
?specialchars_choice: /[_{()\[\]:<>|}]|\$(?![{$])/ // add the internal choice ones
|
|
?specialchars_var: /[_{()\[\]:<>}]|\$(?![{$])/ // add the internal var ones
|
|
?numpar: _WHITESPACE? SIGNED_NUMBER _WHITESPACE?
|
|
|
|
start: promptcomp | content
|
|
|
|
// prompt composition with AND
|
|
promptcomp.4: promptcomppart ( [ ":" numpar ] ( /\bAND\b/ promptcomppart [ ":" numpar ] )+ )+
|
|
promptcomppart: content
|
|
|
|
// simple prompts
|
|
|
|
?old_content.2: ( attention | scheduled | alternate | extranetworktag )+
|
|
//#if ALLOW_NEW_CONTENT
|
|
?content.2: ( old_content | new_content | plain | specialchars )*
|
|
?content_choice.2: ( old_content | new_content | plain_choice | specialchars_choice )*
|
|
?content_var.2: ( old_content | new_content | plain_var | specialchars_var )*
|
|
?content_negtag.2: ( old_content | new_content_negtag | plain | specialchars_negtag )*
|
|
?content_alternate.2: ( old_content | new_content | plain_alternate | specialchars_alternate )*
|
|
?content_en.2: (new_content_en | plain | specialchars )*
|
|
//#if ALLOW_WILDCARDS ALLOW_CHOICES ALLOW_COMMVARS
|
|
?new_content.3: ( variableset | variableuse | commandstn | commandstni | commandset | commandecho | commandif | commandext | wildcard | choices )+
|
|
?new_content_negtag.3: ( variableset | variableuse | commandset | commandecho | commandif | commandext | wildcard | choices )+
|
|
?new_content_en.3: ( variableset | variableuse | commandset | commandecho | commandif | choices )+
|
|
//#elif ALLOW_WILDCARDS !ALLOW_CHOICES ALLOW_COMMVARS
|
|
?new_content.3: ( variableset | variableuse | commandstn | commandstni | commandset | commandecho | commandif | commandext | wildcard )+
|
|
?new_content_negtag.3: ( variableset | variableuse | commandset | commandecho | commandif | commandext | wildcard )+
|
|
?new_content_en.3: ( variableset | variableuse | commandset | commandecho | commandif )+
|
|
//#elif !ALLOW_WILDCARDS ALLOW_CHOICES ALLOW_COMMVARS
|
|
?new_content.3: ( variableset | variableuse | commandstn | commandstni | commandset | commandecho | commandif | commandext | choices )+
|
|
?new_content_negtag.3: ( variableset | variableuse | commandset | commandecho | commandif | commandext | choices )+
|
|
?new_content_en.3: ( variableset | variableuse | commandset | commandecho | commandif | choices )+
|
|
//#elif ALLOW_WILDCARDS ALLOW_CHOICES !ALLOW_COMMVARS
|
|
?new_content.3: ( wildcard | choices )+
|
|
?new_content_negtag.3: ( wildcard | choices )+
|
|
?new_content_en.3: ( choices )+
|
|
//#elif ALLOW_WILDCARDS !ALLOW_CHOICES !ALLOW_COMMVARS
|
|
?new_content.3: ( wildcard )+
|
|
?new_content_negtag.3: ( wildcard )+
|
|
?new_content_en.3: /(?!)./ // never matches
|
|
//#elif !ALLOW_WILDCARDS ALLOW_CHOICES !ALLOW_COMMVARS
|
|
?new_content.3: ( choices )+
|
|
?new_content_negtag.3: ( choices )+
|
|
?new_content_en.3: ( choices )+
|
|
//#elif !ALLOW_WILDCARDS !ALLOW_CHOICES ALLOW_COMMVARS
|
|
?new_content.3: ( variableset | variableuse | commandstn | commandstni | commandset | commandecho | commandif | commandext )+
|
|
?new_content_negtag.3: ( variableset | variableuse | commandset | commandecho | commandif | commandext )+
|
|
?new_content_en.3: ( variableset | variableuse | commandset | commandecho | commandif )+
|
|
//#else
|
|
?new_content.3: ( variableset | variableuse | commandstn | commandstni | commandset | commandecho | commandif | commandext | wildcard | choices )+
|
|
?new_content_negtag.3: ( variableset | variableuse | commandset | commandecho | commandif | wildcard | commandext | choices )+
|
|
?new_content_en.3: ( variableset | variableuse | commandset | commandecho | commandif | choices )+
|
|
//#endif
|
|
//#else
|
|
?content.2: ( old_content | plain | specialchars )*
|
|
?content_choice.2: ( old_content | plain_choice | specialchars_choice )*
|
|
?content_var.2: ( old_content | plain_var | specialchars_var )*
|
|
?content_negtag.2: ( old_content | plain | specialchars_negtag )*
|
|
?content_alternate.2: ( old_content | plain_alternate | specialchars_alternate )*
|
|
?content_en.2: (plain | specialchars )*
|
|
//#endif
|
|
|
|
// attention modifiers
|
|
attention: ( "(" content [ ":" numpar ] ")" ) | ( "[" content "]" )
|
|
|
|
// prompt scheduling and alternation
|
|
alternate: "[" alternateoption ( "|" alternateoption )+ "]"
|
|
alternateoption: content_alternate
|
|
scheduled: "[" [ content ":" ] content ":" numpar "]"
|
|
|
|
// extra network tags
|
|
extranetworktag: "<" /(?!ppp:)\w+:/ encontent ">"
|
|
?encontent.3: content_en
|
|
|
|
// command: stn (send to negative)
|
|
commandstn: "<ppp:stn" [ _WHITESPACE /s|e|p\d/ ] _WHITESPACE? ">" content_negtag "<ppp:/stn>"
|
|
commandstni: "<ppp:stn" _WHITESPACE /i\d/ _WHITESPACE? ">"
|
|
|
|
// command: if
|
|
commandif.2: commandif_if commandif_elif* commandif_else? "<ppp:/if>"
|
|
commandif_if: "<ppp:if" _WHITESPACE condition _WHITESPACE? ">" ifvalue
|
|
commandif_elif: "<ppp:elif" _WHITESPACE condition _WHITESPACE? ">" ifvalue
|
|
commandif_else: "<ppp:else" _WHITESPACE? ">" ifvalue
|
|
ifvalue.3: content
|
|
|
|
// conditions
|
|
?condition: grouped_condition | ungrouped_condition
|
|
?ungrouped_condition: operation | basic_condition
|
|
?grouped_condition.8: "(" _WHITESPACE? condition _WHITESPACE? ")"
|
|
?basic_condition: comparison_simple_value | comparison_list_value | truthy_operand
|
|
?operation: operation_not | operation_and | operation_or
|
|
operation_and: condition _WHITESPACE "and" _WHITESPACE condition
|
|
operation_or: condition _WHITESPACE "or" _WHITESPACE condition
|
|
operation_not: "not" ( ( _WHITESPACE ungrouped_condition ) | ( _WHITESPACE? grouped_condition ) )
|
|
truthy_operand: IDENTIFIER
|
|
comparison_simple_value: IDENTIFIER _WHITESPACE ( /not/ _WHITESPACE )? /eq|ne|gt|lt|ge|le|contains/ _WHITESPACE SIMPLEVALUE
|
|
comparison_list_value: IDENTIFIER _WHITESPACE ( /not/ _WHITESPACE )? /contains|in/ _WHITESPACE listvalue
|
|
listvalue.9: "(" _WHITESPACE? SIMPLEVALUE ( _WHITESPACE? "," _WHITESPACE? SIMPLEVALUE )* _WHITESPACE? ")"
|
|
|
|
// command: set
|
|
commandset: "<ppp:set" _WHITESPACE IDENTIFIER [ commandsetmodifiers ] _WHITESPACE? ">" commandsetcontent "<ppp:/set>"
|
|
commandsetmodifiers: (_WHITESPACE /evaluate|ifundefined|add/ )+
|
|
?commandsetcontent.3: content
|
|
|
|
// command: echo
|
|
commandecho: "<ppp:echo" _WHITESPACE IDENTIFIER _WHITESPACE? ">" [ commandechodefault "<ppp:/echo>" ]
|
|
?commandechodefault.3: content
|
|
|
|
// command: ext
|
|
commandext: "<ppp:ext" _WHITESPACE commandexttype _WHITESPACE commandextid [ _WHITESPACE? commandextparams ] [ _WHITESPACE? commandextif ] _WHITESPACE? ">" [ commandexttriggers "<ppp:/ext>" ]
|
|
commandexttype: [/\$/] IDENTIFIER
|
|
?commandextid: STRING | CNAME
|
|
?commandextparams: STRING | SIGNED_NUMBER
|
|
?commandextif: "if" _WHITESPACE condition
|
|
?commandexttriggers.3: content
|
|
|
|
// variable set
|
|
variableset.2: "${" _WHITESPACE? IDENTIFIER [ variablesetmodifiers ] _WHITESPACE? "=" [ /!/ ] varvalue "}"
|
|
variablesetmodifiers: /[+?!]+/
|
|
|
|
// variable use
|
|
variableuse.2: "${" _WHITESPACE? IDENTIFIER _WHITESPACE? [ ":" varvalue ] "}"
|
|
varvalue: content_var
|
|
|
|
// wildcards
|
|
wildcard.2: "__" [ choicesoptions_sampler | ( choicesoptions _WHITESPACE? "$$" ) ] WILDCARD_NAME [ wc_filter ] [ wildcardvar ] "__"
|
|
wc_filter: /["']/ ( [ /#/ ] wc_filter_or | ( /#?\^/ WILDCARD_NAME ) ) /["']/
|
|
wc_filter_or: wc_filter_and ( _WHITESPACE? "," _WHITESPACE? wc_filter_and )*
|
|
wc_filter_and: INDEX ( _WHITESPACE? "+" _WHITESPACE? INDEX )*
|
|
wildcardvar.7: "(" _WHITESPACE? IDENTIFIER _WHITESPACE? "=" varvalue ")"
|
|
|
|
// choices
|
|
choices.2: "{" [ choicesoptions_sampler | ( choicesoptions _WHITESPACE? "$$" ) ] choice ( "|" choice )* "}"
|
|
|
|
choicesoptions: [ choicesoptions_sampler ] [ _WHITESPACE? choicesoptions_flags ] ( ( [ _WHITESPACE? choicesoptions_from ] "-" [ _WHITESPACE? choicesoptions_to ] ) | [ _WHITESPACE? choicesoptions_num ] ) [ _WHITESPACE? choicesoptions_sep ]
|
|
choicesoptions_sampler: /[~@]/ // ~ for random, @ for cyclical
|
|
choicesoptions_flags: /[ro]{1,2}/ // r for repeating, o for optional
|
|
choicesoptions_num: INT
|
|
choicesoptions_from: INT
|
|
choicesoptions_to: INT
|
|
choicesoptions_sep: "$$" plain
|
|
|
|
choice: [ [ _WHITESPACE? choicelabels ] [ _WHITESPACE? choiceweight ] [ _WHITESPACE? choiceif ] _WHITESPACE? "::" ] choicevalue
|
|
choicelabels: /["']/ IDENTIFIER ( _WHITESPACE? "," _WHITESPACE? IDENTIFIER )* /["']/
|
|
choiceweight: NUMBER
|
|
choiceif: "if" _WHITESPACE condition
|
|
choicevalue: content_choice
|
|
|